2009/05/11(Mon)固定IP→DHCP設定変更バッチファイル

はてブ数 2009/05/11 5:23 のんびり日記::大学 つーさ

実行前の状態を保存して、元に戻すバッチファイルを作る機能付き。
今日使うかもしれないので一応作ってみた。

デスクトップのパスとか取得できたらもっとよかったが、
バッチファイルじゃこの辺が限界かしら。
素直にWSHとかC#とか使えばよかったかもしれない。

まぁ、こんなもん使わなくとも、普通に netsh 打てばいいんだけどさ。

@echo off
setlocal

ipconfig /all
echo.
echo.

set _IPRevertBat="IP設定を元に戻す.bat"
if exist %_IPRevertBat% goto e2

set /p ___nyoro=" IPアドレス設定をDHCPに切り替えますか(Y/N)?"
if /i not "%___nyoro%" == "y" goto e

echo.
echo. 設定中...

echo @echo off > %_IPRevertBat%
echo setlocal >> %_IPRevertBat%
echo netsh int ip reset NUL >> %_IPRevertBat%
echo netsh exec %%0 ^> NUL >> %_IPRevertBat%
echo goto e >> %_IPRevertBat%
netsh int ip dump >> %_IPRevertBat%

echo :e >> %_IPRevertBat%
echo echo パソコンのIP設定を復元しました。>> %_IPRevertBat%
echo set /p ___nyoro="Enterキーを押すと終了します。" >> %_IPRevertBat%
echo endlocal>>%_IPRevertBat%
echo del %%0 >> %_IPRevertBat%

netsh int ip set address "ローカル エリア接続" dhcp > NUL
netsh int ip set address "ローカル エリア接続 2" dhcp > NUL
netsh int ip set address "ローカル エリア接続 3" dhcp > NUL
netsh int ip set address "ワイヤレス ネットワーク接続" dhcp > NUL
netsh int ip set address "ワイヤレス ネットワーク接続 2" dhcp > NUL
netsh int ip set address "ワイヤレス ネットワーク接続 3" dhcp > NUL
ipconfig /renew > NUL
ipconfig /all

echo.
echo. IPアドレス設定をDHCPに切り替えました。
echo. 元に戻すには、"IP設定を元に戻す" を実行してください。
echo.
goto e

:e2
echo.
echo.  IPアドレスを元に戻す.bat が存在します。
echo. 既に環境は変更済みのようです
echo.

:e
set /p ___nyoro=" Enterキーを押すと終了します。"
endlocal